head 1 Calculation of effective conicity according to TU Berlin 
  head 2 Wheel-rail geometry file=kpfr/kpf.kpfr
#
  idebug =  0
#  intsub = e1 tstart 0.00  tstop 6.28318 tout   0.01 tstep 0.01   
  tsim_param= e1  tstart=0.  tstop=6.28318  tstep=0.01  tout=0.01
#
  func   const gauge  1435.
  func   oper  y_delt time - 0.010
  s_var  sngl  y_delt

##
##  Read the wheel-rail geometry file
##  ---------------------------------
   insert file kpfr/kpf.kpfr
   in_substruct kpf_x [ 1 ]
   in_substruct kpf_x [ 2 ]

##
##  Calculate the rolling radiuses at zero lateral displacement
##  -----------------------------------------------------------
  func operp_init   y0_0  ( 1435. - gauge ) / 2000.
  func create_linit drh_0 cpt_1r.drfn y0_0
  func create_linit drv_0 cpt_2r.drfn y0_0
#
  func cos cos_fi time
  func sin sin_fi time
#
#
 substruct integrand [		# arg $1= uy0
#
  func operp yh_$1=( 1435. - gauge ) / 2000. - $1 * sin_fi
  func operp yv_$1=( 1435. - gauge ) / 2000. + $1 * sin_fi

##
##  Interpolate in the wheel-rail geometry function cpt_.drfn
##  ---------------------------------------------------------
  func create_l  drh_$1 cpt_1r.drfn    yh_$1
  func create_l  drv_$1 cpt_2r.drfn    yv_$1

##
##  Calculate the integrand
##  -----------------------
  func operp integrand$1= ( drv_$1 - drv_0 - drh_$1 + drh_0 ) * sin_fi
#
  s_var sngl yh_$1
  s_var sngl drh_$1
  s_var sngl drv_$1
  s_var sngl integrand$1  ]
  s_var scalar_0 time_out

##
##  Call substructure integrand with different gauges
##  ================================================
  in_substruct integrand [ .0005 ]
  in_substruct integrand [ .001 ]
  in_substruct integrand [ .002 ]
  in_substruct integrand [ .004 ]
  in_substruct integrand [ .006 ]
  in_substruct integrand [ .007 ]
  in_substruct integrand [ .008 ]
  in_substruct integrand [ .010 ]
  in_substruct integrand [ .012 ]
eof