head 1 Calculation of the secant conicity for 
  head 2 wheel-rail geometry file kpfr/kpf.kpfr
#
  idebug =  0
  tsim_param= e1  tstart=0.  tstop=0.020  tstep=0.001  tout=0.001
#
  func   oper  y_delt time - 0.010
  s_var  sngl  y_delt

##
##  Read the wheel-rail geometry file
##  =================================
   insert file kpfr/kpf.kpfr
   in_substruct kpf_x [ 1 ]
   in_substruct kpf_x [ 2 ]

##
##  Define a substructure for calculating the conicity lambd_spv
##
##			arg $1=gauge in mm
 substruct conicity [
  func oper yh_$1 ( 1435. - $1 ) / 2000. + time - 0.010
  func oper yv_$1 ( 1435. - $1 ) / 2000. + 0.010 - time

##
##  Interpolate in the wheel-rail geometry function cpt_.drfn
##  =========================================================
  func  create_l  drh_$1 cpt_1r.drfn    yh_$1
  func  create_l  drv_$1 cpt_2r.drfn    yv_$1

##
##  Calculate wheel radius difference and conicity
##  =======================================
  func  oper      lambd_$1  ( drh_$1 - drv_$1 ) / ( yh_$1 - yv_$1 ) 
  s_var sngl drh_$1
  s_var sngl drv_$1
  s_var sngl yh_$1
  s_var sngl yv_$1
  s_var sngl lambd_$1
 ]

##
##  Call substructure conicity with different gauges
##  ================================================
  in_substruct conicity [ 1425 ]
  in_substruct conicity [ 1427 ]
  in_substruct conicity [ 1429 ]
  in_substruct conicity [ 1431 ]
  in_substruct conicity [ 1433 ]
  in_substruct conicity [ 1435 ]
  in_substruct conicity [ 1437 ]
  in_substruct conicity [ 1439 ]
  in_substruct conicity [ 1441 ]
 eof